/* multimove.aml
/*
/*   Called by: editarc.menu
/*		editarcplus.menu
/*		editlabel.menu
/*		edittic.menu
/*		editanno.menu
/*		editgroup.menu
/*  Calls made: none
/*
/* Description:	Allows the user repeatative moves of one feature, by entering
/*		a point to select a feature, which is also the move from
/*		coordinate and entering a move to coordinate.  The user
/*		terminates this repetition by pressing the 9 button on the
/*		mouse.

/* AML setup
&args feature
&severity &error &routine ERROR
&if [show &echo] eq &ON &then
  &messages &on
&else
  &messages &off &all

&ty \Starting multi move, press 9 to quit
&do &until %pnt$key% = 9
  &ty Point to the %feature% to select (also the coordinate to move from) 
  &flushpoints
  &getpoint &current &push
  &if %pnt$key% ne 9 &then &do
    SELECT ONE
    &if [show number select] = 1 &then &do
      &pushpoint 1 %pnt$x% %pnt$y%
      &ty Point to the coordinate to move to
      MOVE
      &ty 1 %feature% moved
      UNSELECT ALL
      &end /* then do
    &else
      &ty No %feature% found ... try again
    &end /* then do
  &end /* do until
&messages &on
&flushpoints
&return

&routine ERROR
&severity &error &ignore
&messages &on
&return; &return &warning An error has occurred in multimove.aml