/* plotmap.aml

/* This AML requires that the logos, location map, and scalebar plotting
/* routines exist under the directory $ARCHOME/gsc/covers for the necessary
/* covers and under the directory $ARCHOME/gsc/amls/arcplot for the plotting
/* amls.

&severity &warning &ignore
&severity &error &routine ERROR
/* Clear screen
CLEAR

/* Setup based on plot option from menu
&s display [extract 2 [show display]]
&select %.plotopt%
  &when Postscript; &do
    &if [exists [locase %.name%].ps -file] &then
      &s x [delete [locase %.name%].ps -file]
    DISPLAY 1040 2
    [locase %.name%].ps
    WEEDDRAW OFF
    &end /* when Postscript
  &when Graphics; &do
    &if [exists [locase %.name%].gra -file] &then
      &s dummy [delete [locase %.name%].gra -file]
    DISPLAY 1040
    [locase %.name%].gra
    WEEDDRAW OFF
    &end /* when Graphics
  &when Display; &do
    /* Kill existing map composition
    &if ^ [null [show map]] &then &do
      &s map [show map]
      MAP END
      KILLMAP %map%
      &end /* then do
    /* Kill map composition if already exists
    &if [exists %.name% -dir] &then
      KILLMAP %.name%
    MAP %.name%
    WEEDDRAW OFF
    &end /* when Display
    WEEDDRAW ON
  &end /* select

/* Establish symbolsets
SHADESET gsc.shd
LINESET gsc.lin
MARKERSET gsc.mrk
TEXTSET gsc.txt

/* Page setup
&s pagex 39.5
&s pagey 26.75
PAGESIZE %pagex% %pagey%
PAGEUNITS INCHES

/* Map number
&s of 3304

/* Border coordinates for positioning map and placement of surround
&s UL 470128 7639530
&s UC 502214 7639371
&s UR 533912 7639578
&s LL 469497 7585917
&s LC 502228 7585757
&s LR 534598 7585971

/* Map setup
&call MAP_SETUP

/* Page Outline
&if %.page% &then &do
  LINESYM 820
  BOX 0 0 %pagex% %pagey%
  &end

/* Trim marks
&if %.trim% &then &do
  &ty ... plotting trim marks
  TRIMMARKS
  &end

/* Select all features
CLEARSELECT

/* Geological polygons
&if %.geopoly% &then &do
  &ty ... plotting geological polygons
  POLYGONSHADES GEO3304OF GEO-SYM
  &ty ... plotting geological contacts
  RESELECT GEO3304OF ARCS GEO-SYM <> 0
  ARCLINES GEO3304OF GEO-SYM
  &end

/* Watermask
&if %.watermask% &then &do
  &ty ... plotting watermask
  RESELECT HYD3304OF POLYS HYD-SYM = 1
  POLYGONSHADES HYD3304OF HYD-SYM
  &end

/* Base
&if %.base% &then &do
  &ty ... plotting base
  ARCLINES HYD3304OF HYD-SYM
  ANNOTEXT TEX3304OF (!MISC BASE!)
  &end

/* Geological lines
&if %.geoline% &then &do
  &ty ... plotting geological lines
  ARCLINES LIN3304OF LIN-SYM
  /* Plot marker symbol for anticline and camp symbol
  POINTMARKERS MSC3304OF MSC-SYM
  &end

/* Geological Symbols
&if %.symbols% &then &do
  &ty ... plotting geological symbols
  POINTMARKERS STR3304OF STR-SYM
  ANNOTEXT TEX3304OF DIPS
  &end

/* Geological Annotation
&if %.anno% &then &do
  &ty ... plotting geological annotation
  ANNOTEXT TEX3304OF UNIT
  &end

/* Map Border
&if %.border% &then &do
  &ty ... plotting map border
  MAPLIMITS PAGE
  RESELECT BOR3304OF POLYS BOR-SYM IN {1,220}
  POLYGONSHADE BOR3304OF BOR-SYM
  ARCLINES BOR3304OF BOR-SYM
  ANNOTEXT BOR3304OF
  &end

/* Surround
&if %.surround% &then &do

  /* Logos
  &ty ... plotting logos
  &call MAP_SETUP
  MAPLIMITS PAGE
  MAPANGLE 0
  NRLOGO BORDER %UL% E R 10
  &call MAP_SETUP
  MAPLIMITS PAGE
  MAPANGLE 0
  GSCLOGO BORDER %UC%
  CNDLOGO LL 0.75 0.75 R

  /* Copies of note
  &call MAP_SETUP
  MAPLIMITS PAGE
  &s x [extract 1 [show convert map %LL% page]]
  &s y [calc [extract 2 [show convert map %LL% page]] - ( 3 / 25.4 )]
  &ty ... plotting copies of note
  TEXTSIZE 6 PT
  TEXTFONT 'Triumvirate Light'
  TEXTQUALITY PROPORTIONAL
  TEXTCOLOR BLACKX
  TEXTANGLE -1.0
  MOVE %x% %y%
  TEXT 'Copies of this map may be obtained' LL
  &s y [calc %y% - ( 8 / 72 )]
  MOVE %x% %y%
  TEXT 'from the Geological Survey of Canada' LL
  &s y [calc %y% - ( 8 / 72 )]
  MOVE %x% %y%
  TEXT '601 Booth Street, Ottawa, Ontario K1A 0E8' LL
  TEXTANGLE 0

  &ty ... plotting title block
  &call MAP_SETUP
  MAPLIMITS PAGE
  &s x [extract 1 [show convert map %LC% page]]
  &s y [calc [extract 2 [show convert map %LC% page]] - ( 8 / 25.4 )]
  MOVE %x% %y%
  TEXTFONT Triumvirate
  TEXTSIZE 10 # PT
  TEXTQUALITY PROPORTIONAL
  TEXTCOLOR CMYK -1 -1 -1 100
  TEXT [quote OPEN FILE %of%] LC
  &s y %y% - ( 20 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXTSIZE 12 # PT
  TEXT 'GEOLOGY' LC
  &s y %y% - ( 32 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXTFONT 'Triumvirate Bold'
  TEXTSIZE 24 # PT
  TEXT 'DUKE OF YORK INLIER, VICTORIA ISLAND' LC
  &s y %y% - ( 22 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXTFONT Triumvirate
  TEXTSIZE 14 # PT
  TEXT 'NORTHWEST TERRITORIES' LC
  MOVE %x% [calc %y% - ( 9 / 25.4 ) ]
  SCALEBAR 100000
  MOVE [calc %.X% - 1.1] %.Y%
  TEXTFONT Univers
  TEXTSIZE 7 # PT
  TEXTQUALITY PROPORTIONAL
  TEXT 'Universal Transverse Mercator Projection' LC
  MOVE [calc %.X% + 1.1] %.Y%
  TEXT 'Projection transverse universelle de Mercator' LC
  &s .Y %.Y% - ( 10 * ( 1 / 72 ) )
  MOVE [calc %.X% - 1.1] %.Y%
  TEXT '© Crown copyrights reserved' LC
  MOVE [calc %.X% + 1.1] %.Y%
  TEXT '© Droits de la Couronne réservés' LC

  /* Publish date
  &call MAP_SETUP
  MAPLIMITS PAGE
  &s x [extract 1 [show convert map %LR% page]]
  &s y [calc [extract 2 [show convert map %LR% page]] - ( 3 / 25.4 )]
  &ty ... plotting publish date
  TEXTSIZE 6 PT
  TEXTFONT 'Triumvirate Light'
  TEXTQUALITY PROPORTIONAL
  TEXTCOLOR BLACKX
  TEXTANGLE 1.0
  MOVE %x% %y%
  TEXT 'Published 1997' LR
  TEXTANGLE 0

  /* Location map
  &call MAP_SETUP
  MAPLIMITS PAGE
  MAPANGLE 0
  &ty ... plotting location map
  LOCATIONMAP LL 0.75 1.60 -110.95 68.625 RED GRIDOFF E

  /* NTS index
  &call MAP_SETUP
  (!LINE SHADE TEXT!)SET GSC
  &ty ... plotting NTS index
  &s x [extract 1 [show convert map %LR% page]]
  MAPEX NTS3304OF
  CLIPMAPEXTENT OFF
  MAPPOSITION 261994 7432110 %x% 1.5
  MAPUNITS METERS
  MAPSCALE 6665900
  MAPANGLE 0
  MAPLIMITS PAGE
  RESEL NTS3304OF POLYS NTS-SYM EQ 4
  POLYGONSHADES NTS3304OF 4
  LINESYMBOL 807
  ARCS NTS3304OF
  TEXTSYMBOL 906
  TEXTSTYLE SIMPLE
  TEXTPUT 906
  ANNOTEXT NTS3304OF

  /* Recommended citation
  &s lines 5
  &s x [calc %pagex% - 3.5 - 0.75] /* page width - citation width - margin
  &s y [calc 0.75 + ( ( %lines% - 1 ) * ( 10 / 72 ) )]
  &s y_of %y%
  TEXTFONT 'Triumvirate Light'
  TEXTSIZE 8 # PT
  TEXTQUALITY PROPORTIONAL
  TEXTCOLOR CMYK -1 -1 -1 100
  MOVE %x% %y%
  TEXT 'Recommended citation:' LL
  &s y %y% - ( 10 * ( 1 / 72 ) )
  &s x %x% + ( 0.5 * ( 1 / 6 ) )
  MOVE %x% %y%
  TEXT 'R.H. Rainbird, A.N. LeCheminant, and I. Lawyer' LL
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT '1997:' LL
  &s x %x% + ( 5 / 16 )
  MOVE %x% %y%
  TEXT 'Geology, Duke of York Inlier, Victoria Island, Northwest Territories;' LL
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT [quote (part of NTS 77B), Geological Survey of Canada, Open File %of%,] LL
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'scale 1:100 000' LL
  /* Open file stamp
  OPENFILE LR [calc %pagex% - 0.75] [calc %y_of% + 0.75] %of% E '04/1997'

  /* Credits
  &call MAP_SETUP
  MAPLIMITS PAGE
  &s x [calc [extract 1 [show convert map %LC% page]] - 6.5]
  &s y [calc [extract 2 [show convert map %LC% page]] - 0.95]
  TEXTFONT 'Triumvirate Light Italic'
  TEXTSIZE 8 # PT
  TEXTQUALITY PROPORTIONAL
  TEXTCOLOR CMYK -1 -1 -1 100
  MOVE %x% %y%
  TEXT ~
  'Geology by R.H. Rainbird, A.N. LeCheminant, Geological Survey of Canada,' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'and I. Laywer, WMC International Ltd., 22 Gurdwara Rd., Nepean,' LC 
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Ontario, K2E 8A2. We thank Charlie Bolt of Coppermine for the use of' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'his cabin on the Nakyoktok River and Danny Knopf of Great Slave' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Helicopter for excellent piloting. Dave Sharpe and Doug Hodgson' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'kindly lent us air photos for some of the fieldwork.' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'The manuscript was reviewed by Charlie Jefferson and Steve Lucas' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'and we thank Tim de Freitas for helpful advice on lower Paleozoic' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'stratigraphy and nomenclature' LC
  &s y %y% - ( 30 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Digital cartography by the Geoscience Information Division' LC
  &s y %y% - ( 30 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Electrostatic plot produced by the Geoscience Information Division' LC
  &s x [calc [extract 1 [show convert map %LC% page]] + 6.5]
  &s y [calc [extract 2 [show convert map %LC% page]] - 0.95]
  MOVE %x% %y%
  TEXT 'Any revisions or additional geological information known to the user' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'would be welcomed by the Geological Survey of Canada' LC
  &s y %y% - ( 30 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Mean magnetic declination 1997, 29°24'' E, increasing 29.3'' W annually' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Readings vary from 28°12'' E in the SE corner to 30°34'' E in the NW corner' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Proximity to the Magnetic North Pole causes compass readings to be erratic' LC
  &s y %y% - ( 30 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Digital base map data compiled by Geomatics Canada, Natural Resources Canada' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'at 1:250 000 scale, and modified by the Geoscience Information Division' LC
  &s y %y% - ( 30 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'Copies of the topographical edition of this map area may be obtained from' LC
  &s y %y% - ( 10 * ( 1 / 72 ) )
  MOVE %x% %y%
  TEXT 'the Canada Map Office, Natural Resources Canada, Ottawa, Ontario K1A 0E9' LC

  &end

/* Notes
&if %.notes% &then &do
  &ty ... plotting notes
  EPS notes.epsi 27 1.25
  &end

/* Figures
&if %.figure% &then &do
  &ty ... plotting figures
  EPS figure.epsi [calc 33.875 - 0.83] [calc 6.875 - 2.82]
  &end

/* Legend
&if %.legend% &then &do
  &call MAP_SETUP
  MAPLIMITS PAGE
  MAPANGLE 0
  &ty ... plotting legend
  &if %.legendopt% eq Ascii &then &do
    UNITS MAP
    SHADESYMBOL 1
    SHADE 472654 7636849 472654 7617625 486327 7617625 486327 7627314 ~
      499115 7627314 499115 7636849
    UNITS PAGE
    LEGEND legend.asc
    &run symleg
    &end /* then do
  &else
    PLOT legend.gra
  &end

/* Finishing plot
&call MAP_SETUP
&select %.plotopt%
  &when Postscript, Graphics
    DISPLAY 9999 3 SIZE 800 800
  &when Map
    &ty Don't forget you have a map composition open
  &end /* select
&return

/* end of PLOTMAP routine
&return

&routine MAP_SETUP
MAPUNITS METERS
MAPSCALE 100000
/* Calculate map angle based on lower left and lower right tic coordinates of
/* border (corners of neatline) to square map to page
MAPANGLE [calc -1 * [radang [atan [calc ~
  ( 7587675 - 7587625 ) / ( 532865 - 471231 )]]]]
MAPEXTENT BOR3304OF
/* NOTE: CLIPMAPEXTENT does not work when a map angle is used therefore
/* MAPLIMITS must be used by converting the map coordinates to page coordinates
MAPLIMITS [show convert map 470660 7586706 page] ~
  [show convert map 533348 7638763 page]
MAPPOSITION %LL% 0.75 4.125
&return

&routine ERROR
&severity &error &ignore
&messages &on
&call MAP_SETUP
&return; &return &warning An Error has occurred